Содержание:
1. Конфигурация ERP Управление Холдингом 2.5
2. Внешний вид обработки и назначения
1. Конфигурация ERP Управление Холдингом 2.5
Требуется разработать обработку загрузки данных (документы Заказ клиента) из эксель листа. По нажатии кнопки «Загрузить данные» табличная часть обработки «Данные загрузки» заполняется данными с типом строка, потом нажимаем кнопку «Загрузить ссылки» и в ссылочные поля сопоставляются ссылки объектов. Потом проверяем загруженные в табличную часть «Данные загрузки», данные по кнопке «Проверить данные». Если предупреждений нет, то создаем документы по кнопке «Создать документы». Созданные документы можно смотреть в табличной части «Созданные документы».
2. Внешний вид обработки и назначения
Загрузка заказ клиента
Процедуры и функции обработки:
&НаКлиенте
Асинх Процедура ЗагрузитьДанные(Команда)
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Заголовок = "Выберите файл";
ПараметрыДиалога.Фильтр = "Таблица Excel | *.xls; *xlsx";
ОписаниеФайла = Ждать ПоместитьФайлНаСерверАсинх(,,, ПараметрыДиалога);
Если ОписаниеФайла <> Неопределено Тогда
ЗагрузитьДанныеНаСервере(ОписаниеФайла.Адрес, ОписаниеФайла.СсылкаНаФайл.Расширение);
КонецЕсли;
КонецПроцедуры
&НаСервере
Процедура ЗагрузитьДанныеНаСервере(АдресДанных, РасширениеФайла)
ПутьКФайлу = ПолучитьИмяВременногоФайла(РасширениеФайла);
Данные = ПолучитьИзВременногоХранилища(АдресДанных);
Данные.Записать(ПутьКФайлу);
ТабДок = Новый ТабличныйДокумент;
Попытка
ТабДок.Прочитать(ПутьКФайлу);
Исключение
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = "Не удалось прочитать файл по причине: " + ОписаниеОшибки();
Сообщение.Сообщить();
Возврат;
КонецПопытки;
Объект.ДанныеЗагрузки.Очистить();
ВысотаТаблицы = ТабДок.ВысотаТаблицы;
Для стр = 9 По ВысотаТаблицы Цикл
Организация = ТабДок.Область(стр, 2).Текст;
СтатусЗаказа = ТабДок.Область(стр, 3).Текст;
НомерЗаказа = ТабДок.Область(стр, 4).Текст;
ДатаЗаказа = ТабДок.Область(стр, 5).Текст;
Операция = ТабДок.Область(стр, 6).Текст;
SAP_КодКлиента = ТабДок.Область(стр, 7).Текст;
Клиент = ТабДок.Область(стр, 8).Текст;
Договор = ТабДок.Область(стр, 9).Текст;
Соглашение = ТабДок.Область(стр, 10).Текст;
Склад = ТабДок.Область(стр, 11).Текст;
Комментарий = ТабДок.Область(стр, 12).Текст;
АртикулНоменклатуры = ТабДок.Область(стр, 13).Текст;
Номенклатура = ТабДок.Область(стр, 14).Текст;
ХарактеристикаНоменклатуры = ТабДок.Область(стр, 15).Текст;
ВариантОбеспеченияНоменклатуры = ТабДок.Область(стр, 16).Текст;
Обособленно = ТабДок.Область(стр, 17).Текст;
ПодразделениеОтправитель = ТабДок.Область(стр, 18).Текст;
ДатаОтгрузки = ТабДок.Область(стр, 19).Текст;
СерийныйНомер = ТабДок.Область(стр, 20).Текст;
ДатаПроизводства = ТабДок.Область(стр, 21).Текст;
БуквенныйКодСпецификации = ТабДок.Область(стр, 22).Текст;
Содержание = ТабДок.Область(стр, 23).Текст;
Количество = ТабДок.Область(стр, 24).Текст;
ЕдИзм = ТабДок.Область(стр, 25).Текст;
ВидЦены = ТабДок.Область(стр, 26).Текст;
Цена = ТабДок.Область(стр, 27).Текст;
ПроцентАвтоматическойСкидки = ТабДок.Область(стр, 28).Текст;
СуммаАвтоматическойСкидки = ТабДок.Область(стр, 29).Текст;
ПроцентРучнойСкидки = ТабДок.Область(стр, 30).Текст;
СуммаРучнойСкидки = ТабДок.Область(стр, 31).Текст;
Сумма = ТабДок.Область(стр, 32).Текст;
СтавкаНДС = ТабДок.Область(стр, 33).Текст;
НДС = ТабДок.Область(стр, 34).Текст;
СуммаСНДС = ТабДок.Область(стр, 35).Текст;
ОтмененПоПричине = ТабДок.Область(стр, 36).Текст;
СпособДоставки = ТабДок.Область(стр, 37).Текст;
АдресДоставкиДляПечати = ТабДок.Область(стр, 38).Текст;
Валюта = ТабДок.Область(стр, 39).Текст;
Подразделение = ТабДок.Область(стр, 40).Текст;
Налогообложение = ТабДок.Область(стр, 41).Текст;
ИнформацияДляПечати = ТабДок.Область(стр, 42).Текст;
НомерЗаказаПоДаннымПоставщика = ТабДок.Область(стр, 43).Текст;
Дата = ТабДок.Область(стр, 44).Текст;
НомерСерии = ТабДок.Область(стр, 45).Текст;
ДокументОснованиеЗаказКлиента = ТабДок.Область(стр, 46).Текст;
НомерСпецификации = ТабДок.Область(стр, 47).Текст;
ВидЗаказа = ТабДок.Область(стр, 48).Текст;
ВидДоставки = ТабДок.Область(стр, 49).Текст;
Если Организация = "" Тогда
Прервать;
КонецЕсли;
НоваяСтрока = Объект.ДанныеЗагрузки.Добавить();
НоваяСтрока.Организация = Организация;
НоваяСтрока.СтатусЗаказа = СтатусЗаказа;
НоваяСтрока.НомерЗаказа = НомерЗаказа;
НоваяСтрока.ДатаЗаказа = СтроковыеФункцииКлиентСервер.СтрокаВДату(ДатаЗаказа, ЧастиДаты.Дата);
НоваяСтрока.Операция = Операция;
НоваяСтрока.SAP_КодКлиента = SAP_КодКлиента;
НоваяСтрока.Клиент = Клиент;
НоваяСтрока.Договор = Договор;
НоваяСтрока.Соглашение = Соглашение;
НоваяСтрока.Склад = Склад;
НоваяСтрока.Комментарий = Комментарий;
НоваяСтрока.АртикулНоменклатуры = АртикулНоменклатуры;
НоваяСтрока.Номенклатура = Номенклатура;
НоваяСтрока.ХарактеристикаНоменклатуры = ХарактеристикаНоменклатуры;
НоваяСтрока.ВариантОбеспеченияНоменклатуры = ВариантОбеспеченияНоменклатуры;
НоваяСтрока.Обособленно = Обособленно;
НоваяСтрока.ПодразделениеОтправитель = ПодразделениеОтправитель;
НоваяСтрока.ДатаОтгрузки = СтроковыеФункцииКлиентСервер.СтрокаВДату(ДатаОтгрузки, ЧастиДаты.Дата);
НоваяСтрока.СерийныйНомер = СерийныйНомер;
НоваяСтрока.ДатаПроизводства = СтроковыеФункцииКлиентСервер.СтрокаВДату(ДатаПроизводства);
НоваяСтрока.БуквенныйКодСпецификации = БуквенныйКодСпецификации;
НоваяСтрока.Содержание = Содержание;
НоваяСтрока.Количество = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(Количество);
НоваяСтрока.ЕдИзм = ЕдИзм;
НоваяСтрока.ВидЦены = ВидЦены;
НоваяСтрока.Цена = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(Цена);
НоваяСтрока.ПроцентАвтоматическойСкидки = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(ПроцентАвтоматическойСкидки);
НоваяСтрока.СуммаАвтоматическойСкидки = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(СуммаАвтоматическойСкидки);
НоваяСтрока.ПроцентРучнойСкидки = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(ПроцентРучнойСкидки);
НоваяСтрока.СуммаРучнойСкидки = СуммаРучнойСкидки;
НоваяСтрока.Сумма = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(Сумма);
НоваяСтрока.СтавкаНДС = ?(СтавкаНДС = "Без НДС", СтавкаНДС, СтавкаНДС + "%");
НоваяСтрока.НДС = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(НДС);
НоваяСтрока.СуммаСНДС = СтроковыеФункцииКлиентСервер.СтрокаВЧисло(СуммаСНДС);
НоваяСтрока.ОтмененПоПричине = ОтмененПоПричине;
НоваяСтрока.СпособДоставки = СпособДоставки;
НоваяСтрока.АдресДоставкиДляПечати = АдресДоставкиДляПечати;
НоваяСтрока.Валюта = Валюта;
НоваяСтрока.Подразделение = Подразделение;
НоваяСтрока.Налогообложение = Налогообложение;
НоваяСтрока.ИнформацияДляПечати = ИнформацияДляПечати;
НоваяСтрока.НомерЗаказаПоДаннымПоставщика = НомерЗаказаПоДаннымПоставщика;
НоваяСтрока.Дата = СтроковыеФункцииКлиентСервер.СтрокаВДату(Дата, ЧастиДаты.Дата);
НоваяСтрока.НомерСерии = НомерСерии;
НоваяСтрока.ДокументОснованиеЗаказКлиента = ДокументОснованиеЗаказКлиента;
НоваяСтрока.НомерСпецификации = НомерСпецификации;
НоваяСтрока.ВидЗаказа = ВидЗаказа;
НоваяСтрока.ВидДоставки = ВидДоставки;
КонецЦикла;
КонецПроцедуры
&НаКлиенте
Процедура ЗагрузитьСсылки(Команда)
ЗагрузитьСсылкиНаСервере();
КонецПроцедуры
&НаСервере
Процедура ЗагрузитьСсылкиНаСервере()
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ДанныеЗагрузки.НомерСтроки КАК НомерСтроки,
| ДанныеЗагрузки.Организация КАК Организация,
| ДанныеЗагрузки.СтатусЗаказа КАК СтатусЗаказа,
| ДанныеЗагрузки.НомерЗаказа КАК НомерЗаказа,
| ДанныеЗагрузки.ДатаЗаказа КАК ДатаЗаказа,
| ДанныеЗагрузки.Операция КАК Операция,
| ДанныеЗагрузки.SAP_КодКлиента КАК SAP_КодКлиента,
| ДанныеЗагрузки.Клиент КАК Клиент,
| ДанныеЗагрузки.Договор КАК Договор,
| ДанныеЗагрузки.Соглашение КАК Соглашение,
| ДанныеЗагрузки.Склад КАК Склад,
| ДанныеЗагрузки.Комментарий КАК Комментарий,
| ДанныеЗагрузки.АртикулНоменклатуры КАК АртикулНоменклатуры,
| ДанныеЗагрузки.Номенклатура КАК Номенклатура,
| ДанныеЗагрузки.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
| ДанныеЗагрузки.ВариантОбеспеченияНоменклатуры КАК ВариантОбеспеченияНоменклатуры,
| ДанныеЗагрузки.Обособленно КАК Обособленно,
| ДанныеЗагрузки.ПодразделениеОтправитель КАК ПодразделениеОтправитель,
| ДанныеЗагрузки.ДатаОтгрузки КАК ДатаОтгрузки,
| ДанныеЗагрузки.СерийныйНомер КАК СерийныйНомер,
| ДанныеЗагрузки.ДатаПроизводства КАК ДатаПроизводства,
| ДанныеЗагрузки.Содержание КАК Содержание,
| ДанныеЗагрузки.Количество КАК Количество,
| ДанныеЗагрузки.ЕдИзм КАК ЕдИзм,
| ДанныеЗагрузки.ВидЦены КАК ВидЦены,
| ДанныеЗагрузки.Цена КАК Цена,
| ДанныеЗагрузки.ПроцентАвтоматическойСкидки КАК ПроцентАвтоматическойСкидки,
| ДанныеЗагрузки.СуммаАвтоматическойСкидки КАК СуммаАвтоматическойСкидки,
| ДанныеЗагрузки.Сумма КАК Сумма,
| ДанныеЗагрузки.СтавкаНДС КАК СтавкаНДС,
| ДанныеЗагрузки.НДС КАК НДС,
| ДанныеЗагрузки.СуммаСНДС КАК СуммаСНДС,
| ДанныеЗагрузки.ОтмененПоПричине КАК ОтмененПоПричине,
| ДанныеЗагрузки.СпособДоставки КАК СпособДоставки,
| ДанныеЗагрузки.АдресДоставкиДляПечати КАК АдресДоставкиДляПечати,
| ДанныеЗагрузки.Валюта КАК Валюта,
| ДанныеЗагрузки.Подразделение КАК Подразделение,
| ДанныеЗагрузки.Налогообложение КАК Налогообложение,
| ДанныеЗагрузки.ИнформацияДляПечати КАК ИнформацияДляПечати,
| ДанныеЗагрузки.НомерЗаказаПоДаннымПоставщика КАК НомерЗаказаПоДаннымПоставщика,
| ДанныеЗагрузки.Дата КАК Дата,
| ДанныеЗагрузки.НомерСерии КАК НомерСерии,
| ДанныеЗагрузки.ДокументОснованиеЗаказКлиента КАК ДокументОснованиеЗаказКлиента,
| ДанныеЗагрузки.НомерСпецификации КАК НомерСпецификации,
| ДанныеЗагрузки.ВидЗаказа КАК ВидЗаказа,
| ДанныеЗагрузки.ВидДоставки КАК ВидДоставки
|ПОМЕСТИТЬ втДанныеЗагрузки
|ИЗ
| &ДанныеЗагрузки КАК ДанныеЗагрузки
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанныеЗагрузки.НомерСтроки КАК НомерСтроки,
| втДанныеЗагрузки.Организация КАК Организация,
| спрОрганизации.Ссылка КАК ОрганизацияСсылка,
| втДанныеЗагрузки.СтатусЗаказа КАК СтатусЗаказа,
| ВЫБОР
| КОГДА втДанныеЗагрузки.СтатусЗаказа = ""К выполнению""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СтатусыЗаказовКлиентов.КОбеспечению)
| КОГДА втДанныеЗагрузки.СтатусЗаказа = ""Не согласован""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СтатусыЗаказовКлиентов.НеСогласован)
| КОГДА втДанныеЗагрузки.СтатусЗаказа = ""К отгрузке""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СтатусыЗаказовКлиентов.КОтгрузке)
| КОГДА втДанныеЗагрузки.СтатусЗаказа = ""Закрыт""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СтатусыЗаказовКлиентов.Закрыт)
| КОНЕЦ КАК СтатусЗаказаСсылка,
| втДанныеЗагрузки.НомерЗаказа КАК НомерЗаказа,
| втДанныеЗагрузки.ДатаЗаказа КАК ДатаЗаказа,
| втДанныеЗагрузки.Операция КАК Операция,
| втДанныеЗагрузки.SAP_КодКлиента КАК SAP_КодКлиента,
| ВЫБОР
| КОГДА втДанныеЗагрузки.Операция = ""Реализация""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РеализацияКлиенту)
| КОНЕЦ КАК ОперацияСсылка,
| втДанныеЗагрузки.Клиент КАК Клиент,
| спрПартнеры.Ссылка КАК КлиентСсылка,
| втДанныеЗагрузки.Договор КАК Договор,
| втДанныеЗагрузки.Соглашение КАК Соглашение,
| втДанныеЗагрузки.Склад КАК Склад,
| спрСклады.Ссылка КАК СкладСсылка,
| втДанныеЗагрузки.Комментарий КАК Комментарий,
| втДанныеЗагрузки.АртикулНоменклатуры КАК АртикулНоменклатуры,
| втДанныеЗагрузки.Номенклатура КАК Номенклатура,
| спрНоменклатура.Ссылка КАК НоменклатураСсылка,
| втДанныеЗагрузки.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
| втДанныеЗагрузки.ВариантОбеспеченияНоменклатуры КАК ВариантОбеспеченияНоменклатуры,
| ВЫБОР
| КОГДА втДанныеЗагрузки.ВариантОбеспеченияНоменклатуры = ""К обеспечению""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыОбеспечения.КОбеспечению)
| КОГДА втДанныеЗагрузки.ВариантОбеспеченияНоменклатуры = ""Отгрузить""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыОбеспечения.Отгрузить)
| КОГДА втДанныеЗагрузки.ВариантОбеспеченияНоменклатуры = ""Со склада""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ВариантыОбеспечения.СоСклада)
| КОНЕЦ КАК ВариантОбеспеченияНоменклатурыСсылка,
| втДанныеЗагрузки.Обособленно КАК Обособленно,
| втДанныеЗагрузки.ПодразделениеОтправитель КАК ПодразделениеОтправитель,
| втДанныеЗагрузки.ДатаОтгрузки КАК ДатаОтгрузки,
| втДанныеЗагрузки.СерийныйНомер КАК СерийныйНомер,
| втДанныеЗагрузки.ДатаПроизводства КАК ДатаПроизводства,
| втДанныеЗагрузки.Содержание КАК Содержание,
| втДанныеЗагрузки.Количество КАК Количество,
| втДанныеЗагрузки.ЕдИзм КАК ЕдИзм,
| втДанныеЗагрузки.ВидЦены КАК ВидЦены,
| спрВидыЦен.Ссылка КАК ВидЦеныСсылка,
| втДанныеЗагрузки.Цена КАК Цена,
| втДанныеЗагрузки.ПроцентАвтоматическойСкидки КАК ПроцентАвтоматическойСкидки,
| втДанныеЗагрузки.СуммаАвтоматическойСкидки КАК СуммаАвтоматическойСкидки,
| втДанныеЗагрузки.Сумма КАК Сумма,
| втДанныеЗагрузки.СтавкаНДС КАК СтавкаНДС,
| спрСтавкиНДС.Ссылка КАК СтавкаНДССсылка,
| втДанныеЗагрузки.НДС КАК НДС,
| втДанныеЗагрузки.СуммаСНДС КАК СуммаСНДС,
| втДанныеЗагрузки.ОтмененПоПричине КАК ОтмененПоПричине,
| втДанныеЗагрузки.СпособДоставки КАК СпособДоставки,
| ВЫБОР
| КОГДА втДанныеЗагрузки.СпособДоставки = ""Самовывоз (с нашего склада)""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СпособыДоставки.Самовывоз)
| КОГДА втДанныеЗагрузки.СпособДоставки = ""До клиента""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.СпособыДоставки.ДоКлиента)
| КОНЕЦ КАК СпособДоставкиСсылка,
| втДанныеЗагрузки.АдресДоставкиДляПечати КАК АдресДоставкиДляПечати,
| втДанныеЗагрузки.Валюта КАК Валюта,
| спрВалюты.Ссылка КАК ВалютаСсылка,
| втДанныеЗагрузки.Подразделение КАК Подразделение,
| втДанныеЗагрузки.Налогообложение КАК Налогообложение,
| ВЫБОР
| КОГДА втДанныеЗагрузки.Налогообложение = ""Продажа облагается НДС""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяНДС)
| КОГДА втДанныеЗагрузки.Налогообложение = ""Продажа не облагается НДС""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаНеОблагаетсяНДС)
| КОГДА втДанныеЗагрузки.Налогообложение = ""Продажа облагается ЕНВД""
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяЕНВД)
| КОНЕЦ КАК НалогообложениеСсылка,
| втДанныеЗагрузки.ИнформацияДляПечати КАК ИнформацияДляПечати,
| втДанныеЗагрузки.НомерЗаказаПоДаннымПоставщика КАК НомерЗаказаПоДаннымПоставщика,
| втДанныеЗагрузки.Дата КАК Дата,
| втДанныеЗагрузки.НомерСерии КАК НомерСерии,
| втДанныеЗагрузки.ДокументОснованиеЗаказКлиента КАК ДокументОснованиеЗаказКлиента,
| втДанныеЗагрузки.НомерСпецификации КАК НомерСпецификации,
| втДанныеЗагрузки.ВидЗаказа КАК ВидЗаказа,
| спрcls_ВидыЗаказов.Ссылка КАК ВидЗаказаСсылка,
| втДанныеЗагрузки.ВидДоставки КАК ВидДоставки,
| спрcls_ВидДоставки.Ссылка КАК ВидДоставкиСсылка
|ПОМЕСТИТЬ втДанные
|ИЗ
| втДанныеЗагрузки КАК втДанныеЗагрузки
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации КАК спрОрганизации
| ПО втДанныеЗагрузки.Организация = спрОрганизации.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Партнеры КАК спрПартнеры
| ПО втДанныеЗагрузки.SAP_КодКлиента = спрПартнеры.cls_КодSAP
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК спрНоменклатура
| ПО втДанныеЗагрузки.АртикулНоменклатуры = спрНоменклатура.Артикул
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Валюты КАК спрВалюты
| ПО втДанныеЗагрузки.Валюта = спрВалюты.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Склады КАК спрСклады
| ПО втДанныеЗагрузки.Склад = спрСклады.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВидыЦен КАК спрВидыЦен
| ПО втДанныеЗагрузки.ВидЦены = спрВидыЦен.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СтавкиНДС КАК спрСтавкиНДС
| ПО втДанныеЗагрузки.СтавкаНДС = спрСтавкиНДС.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.cls_ВидыЗаказов КАК спрcls_ВидыЗаказов
| ПО втДанныеЗагрузки.ВидЗаказа = спрcls_ВидыЗаказов.Наименование
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.cls_ВидДоставки КАК спрcls_ВидДоставки
| ПО втДанныеЗагрузки.ВидДоставки = спрcls_ВидДоставки.Наименование
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанные.ОрганизацияСсылка КАК ОрганизацияСсылка,
| втДанные.КлиентСсылка КАК КлиентСсылка,
| МАКСИМУМ(спрДоговорыКонтрагентов.Ссылка) КАК ДоговорСсылка
|ПОМЕСТИТЬ втДоговоры
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ДоговорыКонтрагентов КАК спрДоговорыКонтрагентов
| ПО втДанные.Договор = спрДоговорыКонтрагентов.Наименование
| И втДанные.ОрганизацияСсылка = спрДоговорыКонтрагентов.Организация
| И втДанные.КлиентСсылка = спрДоговорыКонтрагентов.Партнер
|
|СГРУППИРОВАТЬ ПО
| втДанные.ОрганизацияСсылка,
| втДанные.КлиентСсылка
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанные.ОрганизацияСсылка КАК ОрганизацияСсылка,
| втДанные.КлиентСсылка КАК КлиентСсылка,
| втДанные.ОперацияСсылка КАК ОперацияСсылка,
| МАКСИМУМ(спрСоглашенияСКлиентами.Ссылка) КАК СоглашениеСсылка
|ПОМЕСТИТЬ втСоглашения
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СоглашенияСКлиентами КАК спрСоглашенияСКлиентами
| ПО втДанные.Соглашение = спрСоглашенияСКлиентами.Наименование
| И втДанные.ОперацияСсылка = спрСоглашенияСКлиентами.ХозяйственнаяОперация
| И втДанные.ОрганизацияСсылка = спрСоглашенияСКлиентами.Организация
| И втДанные.КлиентСсылка = спрСоглашенияСКлиентами.Партнер
|
|СГРУППИРОВАТЬ ПО
| втДанные.ОрганизацияСсылка,
| втДанные.КлиентСсылка,
| втДанные.ОперацияСсылка
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанные.НоменклатураСсылка КАК НоменклатураСсылка,
| спрХарактеристикиНоменклатуры.Ссылка КАК ХарактеристикаНоменклатурыСсылка
|ПОМЕСТИТЬ втХарактеристикиНоменклатуры
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ХарактеристикиНоменклатуры КАК спрХарактеристикиНоменклатуры
| ПО втДанные.ХарактеристикаНоменклатуры = спрХарактеристикиНоменклатуры.Наименование
| И втДанные.НоменклатураСсылка = спрХарактеристикиНоменклатуры.Владелец
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанные.НоменклатураСсылка КАК НоменклатураСсылка,
| втДанные.НоменклатураСсылка.ИспользоватьУпаковки КАК ИспользоватьУпаковки,
| втДанные.НоменклатураСсылка.НаборУпаковок КАК НаборУпаковок,
| спрУпаковкиЕдиницыИзмерения.Ссылка КАК ЕдИзмСсылка,
| спрУпаковкиЕдиницыИзмерения.Владелец КАК Владелец,
| спрУпаковкиЕдиницыИзмерения.ТипИзмеряемойВеличины КАК ТипИзмеряемойВеличины
|ПОМЕСТИТЬ втУпаковки
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.УпаковкиЕдиницыИзмерения КАК спрУпаковкиЕдиницыИзмерения
| ПО втДанные.ЕдИзм = спрУпаковкиЕдиницыИзмерения.Наименование
| И втДанные.НоменклатураСсылка = спрУпаковкиЕдиницыИзмерения.Владелец
|ГДЕ
| втДанные.НоменклатураСсылка.ИспользоватьУпаковки
| И спрУпаковкиЕдиницыИзмерения.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.Упаковка)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| втДанные.НоменклатураСсылка,
| втДанные.НоменклатураСсылка.ИспользоватьУпаковки,
| втДанные.НоменклатураСсылка.НаборУпаковок,
| спрУпаковкиЕдиницыИзмерения.Ссылка,
| спрУпаковкиЕдиницыИзмерения.ЕдиницаИзмерения,
| спрУпаковкиЕдиницыИзмерения.ТипИзмеряемойВеличины
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.УпаковкиЕдиницыИзмерения КАК спрУпаковкиЕдиницыИзмерения
| ПО втДанные.ЕдИзм = спрУпаковкиЕдиницыИзмерения.Наименование
|ГДЕ
| НЕ втДанные.НоменклатураСсылка.ИспользоватьУпаковки
| И спрУпаковкиЕдиницыИзмерения.ТипИзмеряемойВеличины = ЗНАЧЕНИЕ(Перечисление.ТипыИзмеряемыхВеличин.КоличествоШтук)
|;
|
|//////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втДанные.НомерСтроки КАК НомерСтроки,
| втДанные.Организация КАК Организация,
| втДанные.ОрганизацияСсылка КАК ОрганизацияСсылка,
| втДанные.СтатусЗаказа КАК СтатусЗаказа,
| втДанные.СтатусЗаказаСсылка КАК СтатусЗаказаСсылка,
| втДанные.НомерЗаказа КАК НомерЗаказа,
| втДанные.ДатаЗаказа КАК ДатаЗаказа,
| втДанные.Операция КАК Операция,
| втДанные.SAP_КодКлиента КАК SAP_КодКлиента,
| втДанные.ОперацияСсылка КАК ОперацияСсылка,
| втДанные.Клиент КАК Клиент,
| втДанные.КлиентСсылка КАК КлиентСсылка,
| спрКонтрагенты.Ссылка КАК КонтрагентСсылка,
| втДанные.Договор КАК Договор,
| втДоговоры.ДоговорСсылка КАК ДоговорСсылка,
| втДанные.Соглашение КАК Соглашение,
| втСоглашения.СоглашениеСсылка КАК СоглашениеСсылка,
| втДанные.Склад КАК Склад,
| втДанные.СкладСсылка КАК СкладСсылка,
| втДанные.Комментарий КАК Комментарий,
| втДанные.АртикулНоменклатуры КАК АртикулНоменклатуры,
| втДанные.Номенклатура КАК Номенклатура,
| втДанные.НоменклатураСсылка КАК НоменклатураСсылка,
| втДанные.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
| втХарактеристикиНоменклатуры.ХарактеристикаНоменклатурыСсылка КАК ХарактеристикаНоменклатурыСсылка,
| втДанные.ВариантОбеспеченияНоменклатуры КАК ВариантОбеспеченияНоменклатуры,
| втДанные.ВариантОбеспеченияНоменклатурыСсылка КАК ВариантОбеспеченияНоменклатурыСсылка,
| втДанные.Обособленно КАК Обособленно,
| втДанные.ПодразделениеОтправитель КАК ПодразделениеОтправитель,
| спрСтруктураПредприятияОтправитель.Ссылка КАК ПодразделениеОтправительСсылка,
| втДанные.ДатаОтгрузки КАК ДатаОтгрузки,
| втДанные.СерийныйНомер КАК СерийныйНомер,
| втДанные.ДатаПроизводства КАК ДатаПроизводства,
| втДанные.Содержание КАК Содержание,
| втДанные.Количество КАК Количество,
| втДанные.ЕдИзм КАК ЕдИзм,
| втУпаковки.ЕдИзмСсылка КАК ЕдИзмСсылка,
| втДанные.ВидЦены КАК ВидЦены,
| втДанные.ВидЦеныСсылка КАК ВидЦеныСсылка,
| втДанные.Цена КАК Цена,
| втДанные.ПроцентАвтоматическойСкидки КАК ПроцентАвтоматическойСкидки,
| втДанные.СуммаАвтоматическойСкидки КАК СуммаАвтоматическойСкидки,
| втДанные.Сумма КАК Сумма,
| втДанные.СтавкаНДС КАК СтавкаНДС,
| втДанные.СтавкаНДССсылка КАК СтавкаНДССсылка,
| втДанные.НДС КАК НДС,
| втДанные.СуммаСНДС КАК СуммаСНДС,
| втДанные.ОтмененПоПричине КАК ОтмененПоПричине,
| втДанные.СпособДоставки КАК СпособДоставки,
| втДанные.СпособДоставкиСсылка КАК СпособДоставкиСсылка,
| втДанные.АдресДоставкиДляПечати КАК АдресДоставкиДляПечати,
| втДанные.Валюта КАК Валюта,
| втДанные.ВалютаСсылка КАК ВалютаСсылка,
| втДанные.Подразделение КАК Подразделение,
| спрСтруктураПредприятия.Ссылка КАК ПодразделениеСсылка,
| втДанные.Налогообложение КАК Налогообложение,
| втДанные.НалогообложениеСсылка КАК НалогообложениеСсылка,
| втДанные.ИнформацияДляПечати КАК ИнформацияДляПечати,
| втДанные.НомерЗаказаПоДаннымПоставщика КАК НомерЗаказаПоДаннымПоставщика,
| втДанные.Дата КАК Дата,
| втДанные.НомерСерии КАК НомерСерии,
| втДанные.ДокументОснованиеЗаказКлиента КАК ДокументОснованиеЗаказКлиента,
| втДанные.НомерСпецификации КАК НомерСпецификации,
| втДанные.ВидЗаказа КАК ВидЗаказа,
| втДанные.ВидЗаказаСсылка КАК ВидЗаказаСсылка,
| втДанные.ВидДоставки КАК ВидДоставки,
| втДанные.ВидДоставкиСсылка КАК ВидДоставкиСсылка
|ИЗ
| втДанные КАК втДанные
| ЛЕВОЕ СОЕДИНЕНИЕ втСоглашения КАК втСоглашения
| ПО втДанные.КлиентСсылка = втСоглашения.КлиентСсылка
| И втДанные.ОрганизацияСсылка = втСоглашения.ОрганизацияСсылка
| И втДанные.ОперацияСсылка = втСоглашения.ОперацияСсылка
| ЛЕВОЕ СОЕДИНЕНИЕ втДоговоры КАК втДоговоры
| ПО втДанные.ОрганизацияСсылка = втДоговоры.ОрганизацияСсылка
| И втДанные.КлиентСсылка = втДоговоры.КлиентСсылка
| ЛЕВОЕ СОЕДИНЕНИЕ втХарактеристикиНоменклатуры КАК втХарактеристикиНоменклатуры
| ПО втДанные.НоменклатураСсылка = втХарактеристикиНоменклатуры.НоменклатураСсылка
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты КАК спрКонтрагенты
| ПО втДанные.КлиентСсылка = спрКонтрагенты.Партнер
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СтруктураПредприятия КАК спрСтруктураПредприятияОтправитель
| ПО втДанные.ПодразделениеОтправитель = спрСтруктураПредприятияОтправитель.Наименование
| И втДанные.ОрганизацияСсылка = спрСтруктураПредприятияОтправитель.Организация
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СтруктураПредприятия КАК спрСтруктураПредприятия
| ПО втДанные.Подразделение = спрСтруктураПредприятия.Наименование
| И втДанные.ОрганизацияСсылка = спрСтруктураПредприятия.Организация
| ЛЕВОЕ СОЕДИНЕНИЕ втУпаковки КАК втУпаковки
| ПО втДанные.НоменклатураСсылка = втУпаковки.НоменклатураСсылка
|
|УПОРЯДОЧИТЬ ПО
| НомерСтроки";
ДанныеЗагрузки = Объект.ДанныеЗагрузки.Выгрузить();
Запрос.УстановитьПараметр("ДанныеЗагрузки", ДанныеЗагрузки);
РезультатЗапроса = Запрос.Выполнить();
мРезультатыЗапроса = Запрос.ВыполнитьПакет();
//мРезультатыЗапроса[6].выгрузить()
//Объект.ДанныеЗагрузки.Загрузить(РезультатЗапроса.Выгрузить());
СтруктураПоиска = Новый Структура;
СписокСвойств = "ОрганизацияСсылка, СтатусЗаказаСсылка, ОперацияСсылка, КлиентСсылка,
|ДоговорСсылка, СоглашениеСсылка, СкладСсылка, НоменклатураСсылка, ХарактеристикаНоменклатурыСсылка,
|ВариантОбеспеченияНоменклатурыСсылка, ВидЦеныСсылка, СтавкаНДССсылка, ЕдИзмСсылка, ВалютаСсылка, ДатаОтгрузки, СпособДоставкиСсылка,
|ПодразделениеОтправительСсылка, ПодразделениеСсылка, НалогообложениеСсылка, КонтрагентСсылка, ВидЗаказаСсылка, ВидДоставкиСсылка";
Выборка = РезультатЗапроса.Выбрать();
Для каждого стр Из Объект.ДанныеЗагрузки Цикл
СтруктураПоиска.Вставить("НомерСтроки", стр.НомерСтроки);
Выборка.НайтиСледующий(СтруктураПоиска);
ЗаполнитьЗначенияСвойств(стр, Выборка, СписокСвойств);
Если ЗначениеЗаполнено(Выборка.НоменклатураСсылка) Тогда
ИспользованиеХарактеристик = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Выборка.НоменклатураСсылка, "ИспользованиеХарактеристик");
Если ИспользованиеХарактеристик = Перечисления.ВариантыИспользованияХарактеристикНоменклатуры.НеИспользовать Тогда
стр.ИспользованиеХарактеристик = Ложь;
Иначе
стр.ИспользованиеХарактеристик = Истина;
КонецЕсли;
КонецЕсли;
Выборка.Сбросить();
КонецЦикла;
КонецПроцедуры
&НаКлиенте
Процедура СоздатьДокументы(Команда)
СоздатьДокументыНаСервере();
КонецПроцедуры
&НаСервере
Процедура СоздатьДокументыНаСервере()
Перем НовыйДок;
к = 0;
ДокЗК = Документы.ЗаказКлиента;
ПервыйНомерЗаказа = 0;
Для каждого стр Из Объект.ДанныеЗагрузки Цикл
НомерЗаказа = стр.НомерЗаказа;
Если НомерЗаказа <> ПервыйНомерЗаказа Тогда
Если ПервыйНомерЗаказа <> 0 Тогда
НовыйДок.Записать();
КонецЕсли;
НовыйДок = ДокЗК.СоздатьДокумент();
ЗаполнитьШапку(НовыйДок, стр);
ЗаполнитьТабЧасть(НовыйДок, стр);
ПервыйНомерЗаказа = НомерЗаказа;
Попытка
НовыйДок.Записать();
СсылкаНаДокумент = НовыйДок.Ссылка;
ДобавитьДокументВТаблицуСозданных(СсылкаНаДокумент);
к = к + 1;
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
Иначе
ЗаполнитьТабЧасть(НовыйДок, стр);
КонецЕсли;
Если к >= 1 Тогда
//Прервать;
КонецЕсли;
КонецЦикла;
НовыйДок.Записать();
Сообщить("Созданы документов в количестве " + к + " штук");
КонецПроцедуры
&НаСервере
Процедура ЗаполнитьШапку(НовыйДок, стр)
ПриоритетСредний = Справочники.Приоритеты.НайтиПоНаименованию("Средний", Истина);
ОплатаВВалюте = ?(Строка(стр.ВалютаСсылка) = "руб.", Истина, Ложь);
НовыйДок.Дата = стр.ДатаЗаказа;
НовыйДок.Организация = стр.ОрганизацияСсылка;
НовыйДок.Приоритет = ПриоритетСредний;
НовыйДок.Контрагент = стр.КонтрагентСсылка;
НовыйДок.Партнер = стр.КлиентСсылка;
НовыйДок.Соглашение = стр.СоглашениеСсылка;
НовыйДок.Валюта = стр.ВалютаСсылка;
НовыйДок.ОплатаВВалюте = ОплатаВВалюте;
НовыйДок.Статус = стр.СтатусЗаказаСсылка;
НовыйДок.Склад = стр.СкладСсылка;
НовыйДок.ХозяйственнаяОперация = стр.ОперацияСсылка;
НовыйДок.Комментарий = стр.Комментарий;
НовыйДок.Договор = стр.ДоговорСсылка;
НовыйДок.Подразделение = стр.ПодразделениеСсылка;
НовыйДок.СпособДоставки = стр.СпособДоставкиСсылка;
НовыйДок.АдресДоставки = стр.АдресДоставкиДляПечати;
НовыйДок.cls_ВидЗаказа = стр.ВидЗаказаСсылка;
НовыйДок.cls_ВидДоставки = стр.ВидДоставкиСсылка;
НовыйДок.НалогообложениеНДС = стр.НалогообложениеСсылка;
НовыйДок.ДополнительнаяИнформация = "№ " + стр.НомерЗаказа + " от " + Формат(стр.ДатаЗаказа, "ДФ=dd.MM.yyyy");
НовыйДок.ЦенаВключаетНДС = Истина;
КонецПроцедуры
&НаСервере
Процедура ЗаполнитьТабЧасть(НовыйДок, стр)
НоваяСтрока = НовыйДок.Товары.Добавить();
НоваяСтрока.Номенклатура = стр.НоменклатураСсылка;
НоваяСтрока.Характеристика = стр.ХарактеристикаНоменклатурыСсылка;
НоваяСтрока.Упаковка = стр.ЕдИзмСсылка;
НоваяСтрока.ВариантОбеспечения = стр.ВариантОбеспеченияНоменклатурыСсылка;
НоваяСтрока.Обособленно = стр.Обособленно;
// НоваяСтрока.ПодразделениеОтправитель = стр.ПодразделениеОтправительСсылка;
НоваяСтрока.Количество = стр.Количество;
НоваяСтрока.КоличествоУпаковок = стр.Количество;
НоваяСтрока.ВидЦены = стр.ВидЦеныСсылка;
НоваяСтрока.Цена = стр.Цена;
НоваяСтрока.СтавкаНДС = стр.СтавкаНДССсылка;
НоваяСтрока.СуммаНДС = стр.НДС;
НоваяСтрока.Сумма = стр.Сумма;
НоваяСтрока.СуммаСНДС = стр.СуммаСНДС;
НоваяСтрока.ПроцентРучнойСкидки = стр.ПроцентРучнойСкидки;
НоваяСтрока.СуммаРучнойСкидки = стр.СуммаРучнойСкидки;
НоваяСтрока.ПроцентАвтоматическойСкидки = стр.ПроцентАвтоматическойСкидки;
НоваяСтрока.СуммаАвтоматическойСкидки = стр.СуммаАвтоматическойСкидки;
// НоваяСтрока.Отменено =стр.ПричинаОтмены;
НоваяСтрока.Содержание = стр.Содержание;
// НоваяСтрока.ВариантОбеспечения = стр.ВариантОбеспеченияНоменклатурыСсылка;
НоваяСтрока.Обособленно = стр.Обособленно;
НоваяСтрока.Подразделение = стр.ПодразделениеСсылка;
НоваяСтрока.ДатаОтгрузки = стр.ДатаОтгрузки;
НоваяСтрока.Подразделение = стр.ПодразделениеОтправительСсылка;
КонецПроцедуры
&НаСервере
Процедура ДобавитьДокументВТаблицуСозданных(СсылкаНаДокумент, ЭтоНовый = Истина)
НоваяСтрока = Объект.СозданныеДокументы.Добавить();
НоваяСтрока.Документ = СсылкаНаДокумент;
НоваяСтрока.Новый = ЭтоНовый;
КонецПроцедуры
&НаКлиенте
Процедура ПроверитьДанные(Команда)
Для каждого стр Из Объект.ДанныеЗагрузки Цикл
Если Не ЗначениеЗаполнено(стр.ОрганизацияСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Организация", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.СтатусЗаказаСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден СтатусЗаказа", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ОперацияСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Операция", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.КлиентСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Клиент", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ДоговорСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Договор", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.СоглашениеСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Соглашение", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.СкладСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Склад", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.НоменклатураСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Номенклатура", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ХарактеристикаНоменклатурыСсылка) Тогда
Если стр.ИспользованиеХарактеристик Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ХарактеристикаНоменклатуры", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ВариантОбеспеченияНоменклатурыСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ВариантОбеспеченияНоменклатуры", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ПодразделениеОтправительСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ПодразделениеОтправитель", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ЕдИзмСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ЕдИзм", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ВидЦеныСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ВидЦены", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ВалютаСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Валюта", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ПодразделениеСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Подразделение", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.НалогообложениеСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден Налогообложение", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ВидЗаказаСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ВидЗаказа", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
Если Не ЗначениеЗаполнено(стр.ВидДоставкиСсылка) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = СтрШаблон("В строке %1 не найден ВидДоставки", стр.НомерСтроки);
Сообщение.Сообщить();
КонецЕсли;
КонецЦикла;
КонецПроцедуры
Специалист компании ООО "Кодерлайн"
Марс Айзатуллов
